Prev |  | Next

## 15.10. Match

### 15.10.1. Introduction

| Tip
In the `MATCH` clause, patterns are used a lot. Read Section 15.8, “Patterns” for an introduction.

The following graph is used for the examples below:

Figure 15.3. Graph

### 15.10.2. Related nodes

The symbol `--` means related to, without regard to type or direction.

Query.

    START n=node(3)
    MATCH (n)--(x)
    RETURN x

All nodes related to A (Anders) are returned by the query.

Result

x
3 rows
0 ms
`Node[4]{name:"Bossman"}`
`Node[1]{name:"David"}`
`Node[5]{name:"Cesar"}`

### 15.10.3. Outgoing relationships

When the direction of a relationship is interesting, it is shown by using `-->` or `<--`, like this:

Query.

    START n=node(3)
    MATCH (n)-->(x)
    RETURN x

All nodes that A has outgoing relationships to are returned.

Result

x
2 rows
0 ms
`Node[4]{name:"Bossman"}`
`Node[5]{name:"Cesar"}`

### 15.10.4. Directed relationships and identifier

If an identifier is needed, either for filtering on properties of the relationship, or to return the relationship, this is how you introduce the identifier.

Query.

    START n=node(3)
    MATCH (n)-[r]->()
    RETURN r

The query returns all outgoing relationships from node A.

Result

r
2 rows
0 ms
`:KNOWS[0] {}`
`:BLOCKS[1] {}`

### 15.10.5. Match by relationship type

When you know the relationship type you want to match on, you can specify it by using a colon together with the relationship type.

Query.

    START n=node(3)
    MATCH (n)-[:BLOCKS]->(x)
    RETURN x

All nodes that are BLOCKed by A are returned by this query.

Result

x
1 row
1 ms
`Node[5]{name:"Cesar"}`

### 15.10.6. Match by multiple relationship types

To match on one of multiple types, you can specify this by chaining them together with the pipe symbol `|`.

Query.

    START n=node(3)
    MATCH (n)-[:BLOCKS|KNOWS]->(x)
    RETURN x

All nodes with a `BLOCK` or `KNOWS` relationship to A are returned.

Result

x
2 rows
0 ms
`Node[5]{name:"Cesar"}`
`Node[4]{name:"Bossman"}`

### 15.10.7. Match by relationship type and use an identifier

If you both want to introduce an identifier to hold the relationship, and specify the relationship type you want, just add them both, like this.

Query.

    START n=node(3)
    MATCH (n)-[r:BLOCKS]->()
    RETURN r

All `BLOCKS` relationships going out from A are returned.

Result

r
1 row
0 ms
`:BLOCKS[1] {}`

### 15.10.8. Relationship types with uncommon characters

Sometime your database will have types with non-letter characters, or with spaces in them. Use ``` (backtick) to quote these.

Query.

    START n=node(3)
    MATCH (n)-[r:`TYPE THAT HAS SPACE IN IT`]->()
    RETURN r

This query returns a relationship of a type with spaces in it.

Result

r
1 row
0 ms
`:TYPE THAT HAS SPACE IN IT[6] {}`

### 15.10.9. Multiple relationships

Relationships can be expressed by using multiple statements in the form of `()--()`, or they can be strung together, like this:

Query.

    START a=node(3)
    MATCH (a)-[:KNOWS]->(b)-[:KNOWS]->(c)
    RETURN a,b,c

The three nodes in the path are returned by the query.

Result

a | b | c
--- | --- | ---
1 row
0 ms
`Node[3]{name:"Anders"}` | `Node[4]{name:"Bossman"}` | `Node[2]{name:"Emil"}`

### 15.10.10. Variable length relationships

Nodes that are a variable number of relationship→node hops away can be found using the following syntax: `-[:TYPE*minHops..maxHops]->`. minHops and maxHops are optional and default to 1 and infinity respectively. When no bounds are given the dots may be omitted.

Query.

    START a=node(3), x=node(2, 4)
    MATCH a-[:KNOWS*1..3]->x
    RETURN a,x

This query returns the start and end point, if there is a path between 1 and 3 relationships away.

Result

a | x
--- | ---
2 rows
1 ms
`Node[3]{name:"Anders"}` | `Node[2]{name:"Emil"}`
`Node[3]{name:"Anders"}` | `Node[4]{name:"Bossman"}`

### 15.10.11. Relationship identifier in variable length relationships

When the connection between two nodes is of variable length, a relationship identifier becomes an collection of relationships.

Query.

    START a=node(3), x=node(2, 4)
    MATCH a-[r:KNOWS*1..3]->x
    RETURN r

The query returns the relationships, if there is a path between 1 and 3 relationships away.

Result

r
2 rows
1 ms
`[:KNOWS[0] {},:KNOWS[3] {}]`
`[:KNOWS[0] {}]`

### 15.10.12. Zero length paths

Using variable length paths that have the lower bound zero means that two identifiers can point to the same node. If the distance between two nodes is zero, they are by definition the same node. Note that when matching zero length paths the result may contain a match even when matching on a relationship type not in use.

Query.

    START a=node(3)
    MATCH p1=a-[:KNOWS*0..1]->b, p2=b-[:BLOCKS*0..1]->c
    RETURN a,b,c, length(p1), length(p2)

This query will return four paths, some of which have length zero.

Result

a | b | c | length(p1) | length(p2)
--- | --- | --- | --- | ---
4 rows
2 ms
`Node[3]{name:"Anders"}` | `Node[3]{name:"Anders"}` | `Node[3]{name:"Anders"}` | `0` | `0`
`Node[3]{name:"Anders"}` | `Node[3]{name:"Anders"}` | `Node[5]{name:"Cesar"}` | `0` | `1`
`Node[3]{name:"Anders"}` | `Node[4]{name:"Bossman"}` | `Node[4]{name:"Bossman"}` | `1` | `0`
`Node[3]{name:"Anders"}` | `Node[4]{name:"Bossman"}` | `Node[1]{name:"David"}` | `1` | `1`

### 15.10.13. Optional relationship

If a relationship is optional, it can be marked with a question mark. This is similar to how a SQL outer join works. If the relationship is there, it is returned. If it’s not, `null` is returned in it’s place. Remember that anything hanging off an optional relationship, is in turn optional, unless it is connected with a bound node through some other path.

Query.

    START a=node(2)
    MATCH a-[?]->x
    RETURN a,x

A node, and `null` are returned, since the node has no outgoing relationships.

Result

a | x
--- | ---
1 row
1 ms
`Node[2]{name:"Emil"}` | `<null>`

### 15.10.14. Optional typed and named relationship

Just as with a normal relationship, you can decide which identifier it goes into, and what relationship type you need.

Query.

    START a=node(3)
    MATCH a-[r?:LOVES]->()
    RETURN a,r

This returns a node, and `null`, since the node has no outgoing `LOVES` relationships.

Result

a | r
--- | ---
1 row
1 ms
`Node[3]{name:"Anders"}` | `<null>`

### 15.10.15. Properties on optional elements

Returning a property from an optional element that is `null` will also return `null`.

Query.

    START a=node(2)
    MATCH a-[?]->x
    RETURN x, x.name

This returns the element x (`null` in this query), and `null` as it’s name.

Result

x | x.name
--- | ---
1 row
1 ms
`<null>` | `<null>`

### 15.10.16. Complex matching

Using Cypher, you can also express more complex patterns to match on, like a diamond shape pattern.

Query.

    START a=node(3)
    MATCH (a)-[:KNOWS]->(b)-[:KNOWS]->(c), (a)-[:BLOCKS]-(d)-[:KNOWS]-(c)
    RETURN a,b,c,d

This returns the four nodes in the paths.

Result

a | b | c | d
--- | --- | --- | ---
1 row
1 ms
`Node[3]{name:"Anders"}` | `Node[4]{name:"Bossman"}` | `Node[2]{name:"Emil"}` | `Node[5]{name:"Cesar"}`

### 15.10.17. Shortest path

Finding a single shortest path between two nodes is as easy as using the `shortestPath` function. It’s done like this:

Query.

    START d=node(1), e=node(2)
    MATCH p = shortestPath( d-[*..15]->e )
    RETURN p

This means: find a single shortest path between two nodes, as long as the path is max 15 relationships long. Inside of the parenthesis you define a single link of a path — the starting node, the connecting relationship and the end node. Characteristics describing the relationship like relationship type, max hops and direction are all used when finding the shortest path. You can also mark the path as optional.

Result

p
1 row
0 ms
`[Node[1]{name:"David"},:KNOWS[2] {},Node[3]{name:"Anders"},:KNOWS[0] {},Node[4]{name:"Bossman"},:KNOWS[3] {},Node[2]{name:"Emil"}]`

### 15.10.18. All shortest paths

Finds all the shortest paths between two nodes.

Query.

    START d=node(1), e=node(2)
    MATCH p = allShortestPaths( d-[*..15]->e )
    RETURN p

This example will find the two directed paths between David and Emil.

Result

p
2 rows
1 ms
`[Node[1]{name:"David"},:KNOWS[2] {},Node[3]{name:"Anders"},:KNOWS[0] {},Node[4]{name:"Bossman"},:KNOWS[3] {},Node[2]{name:"Emil"}]`
`[Node[1]{name:"David"},:KNOWS[2] {},Node[3]{name:"Anders"},:BLOCKS[1] {},Node[5]{name:"Cesar"},:KNOWS[4] {},Node[2]{name:"Emil"}]`

### 15.10.19. Named path

If you want to return or filter on a path in your pattern graph, you can a introduce a named path.

Query.

    START a=node(3)
    MATCH p = a-->b
    RETURN p

This returns the two paths starting from the first node.

Result

p
2 rows
1 ms
`[Node[3]{name:"Anders"},:KNOWS[0] {},Node[4]{name:"Bossman"}]`
`[Node[3]{name:"Anders"},:BLOCKS[1] {},Node[5]{name:"Cesar"}]`

### 15.10.20. Matching on a bound relationship

When your pattern contains a bound relationship, and that relationship pattern doesn’t specify direction, Cypher will try to match the relationship where the connected nodes switch sides.

Query.

    START r=rel(0)
    MATCH a-[r]-b
    RETURN a,b

This returns the two connected nodes, once as the start node, and once as the end node.

Result

a | b
--- | ---
2 rows
1 ms
`Node[3]{name:"Anders"}` | `Node[4]{name:"Bossman"}`
`Node[4]{name:"Bossman"}` | `Node[3]{name:"Anders"}`

### 15.10.21. Match with OR

Strictly speaking, you can’t do `OR` in your `MATCH`. It’s still possible to form a query that works a lot like `OR`.

Query.

    START a=node(3), b=node(2)
    MATCH a-[?:KNOWS]-x-[?:KNOWS]-b
    RETURN x

This query is saying: give me the nodes that are connected to `a`, or `b`, or both.

Result

x
3 rows
2 ms
`Node[4]{name:"Bossman"}`
`Node[5]{name:"Cesar"}`
`Node[1]{name:"David"}`

Copyright © 2013 Neo Technology

Prev | Up | Next
| Home |