Prev |  | Next

## 15.17. With

The ability to chain queries together allows for powerful constructs. In Cypher, the `WITH` clause is used to pipe the result from one query to the next.

`WITH` is also used to separate reading from updating of the graph. Every sub-query of a query must be either read-only or write-only.

Figure 15.10. Graph

### 15.17.1. Filter on aggregate function results

Aggregated results have to pass through a `WITH` clause to be able to filter on.

Query.

    START david=node(1)
    MATCH david--otherPerson-->()
    WITH otherPerson, count(*) as foaf
    WHERE foaf > 1
    RETURN otherPerson

The person connected to David with the at least more than one outgoing relationship will be returned by the query.

Result

otherPerson
1 row
0 ms
`Node[3]{name:"Anders"}`

### 15.17.2. Sort results before using collect on them

You can sort your results before passing them to collect, thus sorting the resulting collection.

Query.

    START n=node(*)
    WITH n
    ORDER BY n.name desc
    LIMIT 3
    RETURN collect(n.name)

A list of the names of people in reverse order, limited to 3, in a collection.

Result

collect(n.name)
1 row
0 ms
`["Emil","David","Cesar"]`

### 15.17.3. Limit branching of your path search

You can match paths, limit to a certain number, and then match again using those paths as a base As well as any number of similar limited searches.

Query.

    START n=node(3)
    MATCH n--m
    WITH m
    ORDER BY m.name desc
    LIMIT 1
    MATCH m--o
    RETURN o.name

Starting at Anders, find all matching nodes, order by name descending and get the top result, then find all the nodes connected to that top result, and return their names.

Result

o.name
2 rows
0 ms
`"Anders"`
`"Bossman"`

### 15.17.4. Alternative syntax of WITH

If you prefer a more visual way of writing your query, you can use equal-signs as delimiters before and after the column list. Use at least three before the column list, and at least three after.

Query.

    START david=node(1)
    MATCH david--otherPerson-->()
    ========== otherPerson, count(*) as foaf ==========
    SET otherPerson.connection_count = foaf

For persons connected to David, the `connection_count` property is set to their number of outgoing relationships.

Result

Properties set: 2
0 ms
`(empty result)`

Copyright © 2013 Neo Technology

Prev | Up | Next
| Home |